Freelog 15/FREELOG 15.ISO/WebMaster/Perl/PERL5106.ZIP/perl5/Lib/Cwd.pm

Perl POD Document | 1995-12-02 | 6.1 KB | 263 lines

package Cwd;
require 5.000;
require Exporter;
require Config;

# Use osname for portability switches (doubled to cheaply avoid -w warning)
my $osname = $Config::Config{'osname'} || $Config::Config{'osname'};


=head1 NAME

getcwd - get pathname of current working directory

=head1 SYNOPSIS

    use Cwd;
    $dir = cwd;

    use Cwd;
    $dir = getcwd;

    use Cwd;
    $dir = fastgetcwd;

    use Cwd 'chdir';
    chdir "/tmp";
    print $ENV{'PWD'};

=head1 DESCRIPTION

The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
in Perl.

The fastgetcwd() function looks the same as getcwd(), but runs faster.
It's also more dangerous because you might conceivably chdir() out of a
directory that you can't chdir() back into.

The cwd() function looks the same as getcwd and fastgetcwd but is
implemented using the most natural and safe form for the current
architecture. For most systems it is identical to `pwd` (but without
the trailing line terminator). It is recommended that cwd (or another
*cwd() function) is used in I<all> code to ensure portability.

If you ask to override your chdir() built-in function, then your PWD
environment variable will be kept up to date.  (See
L<perlsub/Overriding builtin functions>.) Note that it will only be
kept up to date it all packages which use chdir import it from Cwd.

=cut

@ISA = qw(Exporter);
@EXPORT = qw(cwd getcwd fastcwd);
@EXPORT_OK = qw(chdir);

use strict;

sub cwd {  # The 'natural and safe form' for UNIX (pwd may be setuid root)
    my $cwd;
    chomp($cwd = `pwd`);
    $cwd;
}


# By Brandon S. Allbery
#
# Usage: $cwd = getcwd();

sub getcwd
{
    my($dotdots, $cwd, @pst, @cst, $dir, @tst);

    unless (@cst = stat('.'))
    {
    warn "stat(.): $!";
    return '';
    }
    $cwd = '';
    $dotdots = '';
    do
    {
    $dotdots .= '/' if $dotdots;
    $dotdots .= '..';
    @pst = @cst;
    unless (opendir(PARENT, $dotdots))
    {
        warn "opendir($dotdots): $!";
        return '';
    }
    unless (@cst = stat($dotdots))
    {
        warn "stat($dotdots): $!";
        closedir(PARENT);
        return '';
    }
    if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
    {
        $dir = '';
    }
    else
    {
        do
        {
        unless (defined ($dir = readdir(PARENT)))
            {
            warn "readdir($dotdots): $!";
            closedir(PARENT);
            return '';
        }
        unless (@tst = lstat("$dotdots/$dir"))
        {
            warn "lstat($dotdots/$dir): $!";
            closedir(PARENT);
            return '';
        }
        }
        while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
           $tst[1] != $pst[1]);
    }
    $cwd = "$dir/$cwd";
    closedir(PARENT);
    } while ($dir);
    chop($cwd); # drop the trailing /
    $cwd;
}



# By John Bazik
#
# Usage: $cwd = &fastcwd;
#
# This is a faster version of getcwd.  It's also more dangerous because
# you might chdir out of a directory that you can't chdir back into.

sub fastcwd {
    my($odev, $oino, $cdev, $cino, $tdev, $tino);
    my(@path, $path);
    local(*DIR);

    ($cdev, $cino) = stat('.');
    for (;;) {
    my $direntry;
    ($odev, $oino) = ($cdev, $cino);
    chdir('..');
    ($cdev, $cino) = stat('.');
    last if $odev == $cdev && $oino == $cino;
    opendir(DIR, '.');
    for (;;) {
        $direntry = readdir(DIR);
        next if $direntry eq '.';
        next if $direntry eq '..';

        last unless defined $direntry;
        ($tdev, $tino) = lstat($direntry);
        last unless $tdev != $odev || $tino != $oino;
    }
    closedir(DIR);
    unshift(@path, $direntry);
    }
    chdir($path = '/' . join('/', @path));
    $path;
}


# Keeps track of current working directory in PWD environment var
# Usage:
#    use Cwd 'chdir';
#    chdir $newdir;

my $chdir_init = 0;

sub chdir_init {
    if ($ENV{'PWD'}) {
    my($dd,$di) = stat('.');
    my($pd,$pi) = stat($ENV{'PWD'});
    if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
        $ENV{'PWD'} = cwd;
    }
    }
    else {
    $ENV{'PWD'} = cwd;
    }
    # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
    if ($ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|) {
    my($pd,$pi) = stat($2);
    my($dd,$di) = stat($1);
    if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
        $ENV{'PWD'}="$2$3";
    }
    }
    $chdir_init = 1;
}

sub chdir {
    my $newdir = shift || '';    # allow for no arg (chdir to HOME dir)
    $newdir =~ s|///*|/|g;
    chdir_init() unless $chdir_init;
    return 0 unless CORE::chdir $newdir;
    if ($osname eq 'VMS') { return $ENV{'PWD'} = $ENV{'DEFAULT'} }

    if ($newdir =~ m#^/#) {
    $ENV{'PWD'} = $newdir;
    } else {
    my @curdir = split(m#/#,$ENV{'PWD'});
    @curdir = ('') unless @curdir;
    my $component;
    foreach $component (split(m#/#, $newdir)) {
        next if $component eq '.';
        pop(@curdir),next if $component eq '..';
        push(@curdir,$component);
    }
    $ENV{'PWD'} = join('/',@curdir) || '/';
    }
    1;
}


# --- PORTING SECTION ---

# VMS: $ENV{'DEFAULT'} points to default directory at all times
# 08-Dec-1994  Charles Bailey  [e-mail]
# Note: Use of Cwd::getcwd() or Cwd::chdir() (but not Cwd::fastcwd())
#   causes the logical name PWD to be defined in the process
#   logical name table as the default device and directory
#   seen by Perl. This may not be the same as the default device
#   and directory seen by DCL after Perl exits, since the effects
#   the CRTL chdir() function persist only until Perl exits.
# This does not apply to other systems (where only chdir() sets PWD).

sub _vms_cwd {
    return $ENV{'DEFAULT'}
}
sub _vms_pwd {
    return $ENV{'PWD'} = $ENV{'DEFAULT'}
}

sub _NT_cwd {
  main::NTGetCwd @_;
}

if ($osname eq 'VMS') {

    *cwd        = \&_vms_pwd;
    *getcwd     = \&_vms_pwd;
    *fastgetcwd = \&_vms_cwd;
}
elsif ($osname eq 'MSWin32') {
    *cwd        = \&_NT_cwd;
    *getcwd     = \&_NT_cwd;
    *fastgetcwd = \&_NT_cwd;
}

# package main; eval join('',<DATA>) || die $@;    # quick test

1;

__END__
BEGIN { import Cwd qw(:DEFAULT chdir); }
print join("\n", cwd, getcwd, fastcwd, "");
chdir('..');
print join("\n", cwd, getcwd, fastcwd, "");
print "$ENV{PWD}\n";